Release 10.1A: OpenEdge Development:
Progress 4GL Reference

DEFINE IMAGE statement


(Windows only; Graphical interfaces only)

Defines a static image widget in a graphical interface for use in the current procedure. An image widget is a container for an operating system image file and can be displayed in a form or used as a form background.

Note: Does not apply to SpeedScript programming.

Syntax 

DEFINE [ PRIVATE ] IMAGE image-name
  { image-phrase | LIKE image | size-phrase }
  [ BGCOLOR expression ]
  [ FGCOLOR expression ]
  [ CONVERT-3D-COLORS ]
  [ TOOLTIP tooltip ]
  [ STRETCH-TO-FIT [ RETAIN-SHAPE ] ] [ TRANSPARENT ]

[ PRIVATE ] IMAGE image-name

Defines and identifies an image widget as a data member for a class, and optionally specifies an access mode for that data member. Do not specify the access mode when defining an image widget for a method within a class.

PRIVATE data members can be accessed only by the defining class. The default access mode is PRIVATE.

Note: This option is applicable only when defining a data member for a class in a class definition (.cls) file.

IMAGE image-name

Identifies the name by which the image widget is referenced. You can define the image widget in a procedure or a method within a class.

image-phrase

Specifies the file where the image is stored and the portion of the image to read. This is the syntax for image-phrase: 

FILE name
  [ { IMAGE-SIZE | IMAGE-SIZE-CHARS | IMAGE-SIZE-PIXELS }
      width BY height
  ]
  [ FROM { { X n Y n } | { ROW n COLUMN n } } ]

For more information on this syntax, see the Image phrase reference entry.

You must specify either the LIKE option, an Image phrase or a Size phrase within the DEFINE IMAGE statement, and you may specify any two or all three.

LIKE image

Specifies a previously defined image from which this image inherits attributes. You can override specific attributes by specifying other options of the DEFINE IMAGE statement.

You must specify either the LIKE option, an Image phrase or a Size phrase within the DEFINE IMAGE statement, and you may specify any two or all three.

size-phrase

Specifies the outside dimensions of the image widget. This is the syntax for size-phrase: 

{ SIZE | SIZE-CHARS | SIZE-PIXELS } width BY height

If you specify SIZE or SIZE-CHARS, the units are characters; if you specify SIZE-PIXELS, the units are pixels. If you use character units, the values width and height must be decimal constants; for pixel units, they must be integer constants. For more information, see the SIZE phrase reference entry.

You must specify either the LIKE option, an Image phrase or a Size phrase within the DEFINE IMAGE statement, and you may specify any two or all three.

BGCOLOR expression

Has no effect; supported only for backward compatibility.

FGCOLOR expression

Has no effect; supported only for backward compatibility.

CONVERT-3D-COLORS

Specifies that the colors associated with an image will be converted to the system 3D colors when an image is loaded. Table 25 describes the color conversion process.

Table 25: 3D-color conversions for images 
If the color is ...
And the original Red-Green-Blue (RGB) color value is ...
Then the new converted system color is ...
White
(255, 255, 255)
System button highlight color.
Light Gray
(192, 192, 192)
System button face color.
Dark Gray
(128, 128, 128)
System button shadow color.
Black
(0, 0, 0)
System button text color.

During a session, if Windows notifies Progress that the system colors are changed, all images that have this option are reloaded and converted to the new system colors.

TOOLTIP tooltip

Allows you to define a help text message for an image widget. Progress automatically displays this text when the user pauses the mouse pointer over the image widget.

You can add or change the TOOLTIP option at any time. If TOOLTIP is set to "" or the Unknown value (?), then the ToolTip is removed from the button. No ToolTip is the default. ToolTips are supported in Windows only.

STRETCH-TO-FIT

Forces the image to expand or contract to fit within the image widget’s boundaries.

This option has no effect if an icon is displayed on the image widget.

RETAIN-SHAPE

Indicates that the image should retain its aspect ratio (expand or contract equally in both dimensions). This may leave some uncovered space at the bottom or right of the image widget.

RETAIN-SHAPE is ignored if STRETCH-TO-FIT is FALSE or if an icon is displayed on the image widget.

TRANSPARENT

Indicates that the background color of the image is transparent. The background color is determined by the color of the pixel in the lower left corner of the image.

The TRANSPARENT option overrides the CONVERT-3D-COLORS option; if both are set, CONVERT-3D-COLORS is ignored.

This option has no effect if an icon is displayed on the image widget.

Example

This procedure defines an image widget named trashcan, and loads into the widget a series of operating system image files that create an animation of a fire burning in a trash can. The user begins the animation by choosing the Animate button. The procedure depends on the existence of image filenames ANI01, ANI02. ... ANI14.

r-image.p 
DEFINE VARIABLE repeat_loop AS INTEGER.
DEFINE VARIABLE animation_loop AS INTEGER.
DEFINE VARIABLE ok AS LOGICAL.
DEFINE BUTTON animate LABEL "Animate".
DEFINE IMAGE trashcan FILE "ANI01.BMP".
DISPLAY animate trashcan WITH FRAME y TITLE "**  Animation Sample  **".

ON CHOOSE OF animate IN FRAME y DO:
  /* Begin Animation */
  DO repeat_loop = 1 TO 5:
    DO animation_loop = 1 TO 14:
      ok = trashcan:LOAD-IMAGE("ANI" + STRING(animation_loop,"99")) 
        IN FRAME y.
    END.
  END.
END.
UPDATE animate WITH FRAME y.

Notes

See also

FORM statement, Image phrase

Copyright © 2005 Progress Software Corporation
 www.progress.com
Voice: (781) 280-4000
Fax: (781) 280-4095